**********************************************************************
*                                                                    *
* HivnetWide.do                                                      *
*                                                                    *
* PURPOSE:  read the data in HivnetWide.dat and format variables     *
*                                                                    *
* DATE:  01/03/27                                                    *
*                                                                    *
**********************************************************************

***
*** read data from the file HivnetWide.dat
***

#delimit ;
infile    id 
          rgroup 
          educ 
          age 
          cohort 
          ICgroup 
          will0 
          know0 
          q4safe0 
          q4safe6 
          q4safe12 
          nurse0 
          nurse6 
          nurse12 
          using U:\DEPT\513\WK1\HivnetWide.dat ;
#delimit cr


***
*** label the variables
***

label variable rgroup "risk group"
label variable educ "highest education"
label variable age "age (yrs)"
label variable cohort "new/rollover"
label variable ICgroup "Informed Consent group"
label variable will0 "willingness at baseline"
label variable know0 "baseline knowledge score"
label variable q4safe0 "safety knowledge at t=0"
label variable q4safe6 "safety knowledge at t=6"
label variable q4safe12 "safety knowledge at t=12"
label variable nurse0 "allocation knowledge at t=0"
label variable nurse6 "allocation knowledge at t=6"
label variable nurse12 "allocation knowledge at t=12"

***
*** label variable categories
***

label define rlab 1 "MSM" 2 "Male IDU" 3 "WAHR" 4 "WAHR+IDU"
label values rgroup rlab

label define elab 1 "<high school" 2 "high school" 3 "some college" 4 "college" 5 "some post" 6 "grad/prof"
label values educ elab


***
*** Univariate summaries
***

tabulate rgroup 
tabulate educ 
tabulate ICgroup 
tabulate will0 
tabulate know0 
tabulate nurse0 
tabulate nurse6 
tabulate nurse12
***
***  Note:  the above could have been obtained with the following
***         tab1 rgroup educ ICgroup will0 know0 nurse0 nurse6 nurse12
***

summarize age

***
*** Bivariate summaries (first for q4safe at baseline)
***

*
***** first method is a simple crosstab (with pearson's chi2)
*
tabulate rgroup q4safe0, row chi
*
* Q:  do we see evidence that knowledge varies by risk group?

*
***** second method stratifies (separates) risk groups
*
sort rgroup
by rgroup: tabulate q4safe0

*
***** third method uses "if" to subset on rgroup levels
*
tabulate q4safe0 if rgroup==1
tabulate q4safe0 if rgroup==2
tabulate q4safe0 if rgroup==3
tabulate q4safe0 if rgroup==4

*
* now knowledge item by other variables...
*
sort know0
by know0: tabulate q4safe0

sort educ
by educ: tabulate q4safe0

sort cohort
by cohort: tabulate q4safe0



***
*** let's run some of the key EPITAB commands for q4safe
***

* Q:  does this make sense for these data?

cc q4safe0 ICgroup
cc q4safe6 ICgroup


* Q:  does this make sense for these data?

cs q4safe0 ICgroup
cs q4safe6 ICgroup


*
* inspect each univariate distribution
* to be sure that you understand the mcc output...
*
tabulate q4safe0 if ICgroup==0
tabulate q4safe6 if ICgroup==0

* Q: can you interpret the odds ratio for each of these?

mcc q4safe0 q4safe6 if ICgroup==0
mcc q4safe6 q4safe0 if ICgroup==0

*
* now consider the intervention group
*

tabulate q4safe0 if ICgroup==1
tabulate q4safe6 if ICgroup==1

mcc q4safe0 q4safe6 if ICgroup==1
mcc q4safe6 q4safe0 if ICgroup==1