*****************************************************************************
* MayoSub-do.txt                                                            *
*                                                                           *
* PURPOSE:  analysis of the PBC data                                        *
*                                                                           *
* DATE:  01/05/05                                                           *
*                                                                           *
*****************************************************************************
***
*** Mayo Model Variables
***
***	 1. age					
***	 2. albumin				
***	 5. serum bilirubin			
***	 8. edema treatment			
***	12. prothrombin time			
***	16. stage				
***
***	10. time				
***	17. censoring				
***						
*****************************************************************************

***
*** input the data and recode -9 to missing
***

#delimit;
infile 
         age
         albu
         bili
         edema
         time
         proth
         stage
         status     using MayoSub.dat ;
#delimit cr

***
*** recode
***
generate logalb = log(albu)
generate logbil = log(bili)
generate logpro = log(proth)


recode stage    -9=.

***
*** labels
***
label variable time "time (days)"
label variable status "status"

***
*** EDA for predictors
***
summarize logalb
centile logalb, centile( 10 25 50 75 90 )

summarize logbil
centile logbil, centile( 10 25 50 75 90 )

summarize age
centile age, centile( 10 25 50 75 90 )

summarize logpro
centile logpro, centile( 10 25 50 75 90 )

***
*** this defines the failure outcome 
***
stset time, failure(status)

***
*** Cox regression
***
stcox logbil logalb age logpro edema, nohr scaledsch(resid0*) esr(esr*)


***
*** compute delta-betas  (optional!)
***
set matsize 400
mkmat esr1 esr2 esr3 esr4 esr5, matrix(esr)
mat V = e(V)
mat Inf = esr*V
svmat Inf, names(dfb)
label var dfb1 "dfbeta log(bili)"
label var dfb2 "dfbeta log(albu)"
label var dfb3 "dfbeta Age"
label var dfb4 "dfbeta log(prot)"
label var dfb5 "dfbeta Edema"

graph dfb1 time, yline(0) 

graph dfb2 time, yline(0) 

graph dfb3 time, yline(0) 

graph dfb4 time, yline(0) 

graph dfb5 time, yline(0)